Usando Access

Vídeo - Criando Ribbons - parte 2 ( English Version )

Aonde as Ribbons ficam armazenadas ?

As ribbons podem ficar armazenadas em três locais distintos:

1 - numa tabela de sistema, de nome USysRibbons que você mesmo deve criá-la;
2 - numa tabela comum, com qualquer nome que você deseje dar a ela;
3 - fora do Access, num arquivo com extensão XML.

Quais campos devemos criar nas tabelas ?

id - AutoNumeração;
RibbonName - Texto - 255;
RibbonXml - Memorando.

Qual é a diferença entre a tabela de sistema e a tabela comum ?

Na tabela de sistema UsysRibbons , as ribbons já são carregadas no seu aplicativo , sem a necessidade de qualquer programação.  Seus nomes aparecem na lista de propriedades dos objetos e na configuração de inicialização do aplicativo.

 A figura abaixo apresenta a configuração de inicialização da Ribbons, que fica nas Opções do Access em Banco de Dados Atual.

Aparecem também na lista de propriedades de formulários e relatórios:

Como carregar no sistema, as ribbons armazenadas de tabela comum (tblRibbons) e do arquivo XML?

Você deve usar a macro AutoExec para executar uma função que carregue na inicialização do aplicativo, as ribbons armazenadas  na tabela ou arquivo XML.

Veja o código exemplo que carrega as ribbons no sistema, armazenadas na tabela tblRibbons:

Public Function fncCarregaRibbon()

Dim rsRib As DAO.Recordset
On Error GoTo TrataErro
'-----------------------------------------------------------------
'Esta função carrega as ribbons armazenadas na tabela tblRibbons,
'que deve ser chamada pela macro autoexec
'
'Crie a macro autoexec, selecione a ação EXECUTARCÓDIGO
'e escreva o nome da função no argumento: fncCarregaRibbon()
'------------------------------------------------------------------
Set rsRib = CurrentDb.OpenRecordset("tblRibbons", dbOpenDynaset)
Do While Not rsRib.EOF
  Application.LoadCustomUI rsRib!RibbonName, rsRib!RibbonXml
  rsRib.MoveNext
Loop
rsRib.Close
Set rsRib = Nothing

Sair:
  Exit Function
TrataErro:
  Select Case Err.Number
    Case 3078
      MsgBox "Tabela não encontrada...", vbInformation, "Aviso"
    Case Else

      MsgBox "Erro: " & Err.Number & vbCrLf & Err.Description, _

      vbCritical, "Aviso", Err.HelpFile, Err.HelpContext
  End Select
  Resume Sair:
End Function

Agora, observe o código exemplo que carrega as ribbons no sistema, armazenadas no arquivo XML:

Public Function fncCarregaRibbonXml()
Dim f As Long
Dim strText As String
Dim strOut As String
Dim rsXml As DAO.Recordset
On Error GoTo TrataErro

'------------------------------------------------------------------------------
'Esta função carrega as ribbons de arquivos XML,
'que deve ser chamada pela macro autoexec
'
'Crie a macro autoexec, selecione a açõa EXECUTARCÓDIGO
'e escreva o nome da função no argumento: fncCarregaRibbonXml()
'
'Crie uma tabela de nome tblRibbonsXml com os campos:
'RibbonName - Este campo você armazena o nome que deseja dar a ribbon
'RibbonXml - Este campo você informa o nome do arquivo Xml
'
'Este exemplo pressupõe que você esteja com os arquivos XML no 

'mesmo local do seu BD
'------------------------------------------------------------------------------
f = FreeFile
Set rsXml = CurrentDb.OpenRecordset("tblRibbonsXml", , dbOpenDynaset)
Do While Not rsXml.EOF
   Open CurrentProject.Path & "\" & rsXml!RibbonXml For Input As f

   Do While Not EOF(f)
      Line Input #f, strText
      strOut = strOut & strText & vbCrLf
   Loop

   Application.LoadCustomUI rsXml!RibbonNome, strOut
   strOut = ""
   strText = ""
   f = FreeFile
   rsXml.MoveNext
Loop

Sair:
   Exit Function
TrataErro:
   Select Case Err.Number
      Case 3078
         MsgBox "Tabela não encontrada...", vbInformation, "Aviso"
      Case Else
         MsgBox "Erro: " & Err.Number & vbCrLf & Err.Description, _

         vbCritical, "Aviso", Err.HelpFile, Err.HelpContext
   End Select
   Resume Sair:
End Function

É preciso referenciar uma classe do Office

Para se ter acesso às propriedades das ribbons pelo vba é necessário referenciar a classe Microsoft Office 12.0 Object Library.

Abra o VBA e no menu Ferramentas, clique em Referências.

Selecione Microsfot Office 12.0 Object Library

Qual atributo devemos usar para dar funcionalidade aos botões de uma ribbon ?

O atributo utilizado para isso é o onAction.  Com ele podemos chamar uma função ou uma macro para executar uma determinada ação, como por exemplo , a abertura de um formulário.

É aqui que você verá a funcionalidade do id, do qual falei bastante  na primeira aula.

Um exemplo de controle Button com o atributo onAction:

<button
id = "btClientes"
imageMso = "DistributionListSelectMembers"
label = "Clientes"
onAction = "fncOnAction"
/>

Agora, observe o código da função fncOnAction:

Public Sub fncOnAction(control As IRibbonControl)

Select Case control.Id
   Case "btClientes"
      Docmd.OpenForm "frmClientes" 'Abre formulário cliente
   Case Else
       MsgBox "Você clicou no botão " & control.Id, vbInformation, "Aviso"
End Select

End Sub

O control.id tem o valor Id do botão que foi clicado e com o SELECT, configuramos o comando adequado a ser aplicado para o botão acionado.

Conheça o controle splitButton:

O controle splitButton em conjunto com o controle buttom são os controles mais usados e suficientes para a maioria dos projetos.

Veja na figura, um splitButton:

Observe abaixo, a estrutura do splitButton e veja que ele trabalha em conjunto com os controles MENU e BUTTON.  O exemplo desta montagem, você verá na vídeo-aula.

Aplicativo exemplo

Montei um pequeno arquivo exemplo para você estudar e exercitar esta aula. Este arquivo exemplo inclui o controle de usuários que é explicado neste artigo.

Baixe aqui o exemplo

Vídeo-aula

Nesta vídeo-aula, você irá aprender como configurar o controle splitButton.  Irá acompanhar como exportar as ribbons para o aplicativo exemplo e por fim, aprenderá como configurar a função que dá funcionalidade aos botões da ribbon.

Como EXIBIR a vídeo-aula em tela cheia?

1. clique na seta executar da tela abaixo para iniciar a exibição do vídeo;

2. dê dois cliques rápidos na tela, quando o vídeo começar a ser exibido.

| Home | Vídeos-aulas | Tutoriais | Dicas | Blog | Downloads | Contato | Artigo |