... Assinatura do site por 3 anos + Kit MontaRibbons + 3 Livros em PDF + Diversas Revistas (pdf) de brinde, por apenas R$135,00
(
podendo parcelar em até 10 vezes no cartão de crédito)...

Clique aqui e obtenha mais detalhes do nosso kit completo e de como comprar.


Criar planilha Excel através do Microsoft Access

Acompanhe, atentamente, os comentários do código e veja como é simples criar uma planilha do Excel e introduzir dados às Células desejadas:

Public Sub fncCriarPlanilha()
Dim xlApp As Object
Dim wkb As Object
Dim objSheet As Object
'Abre o Excel
Set xlApp = CreateObject("excel.application")
'Torna o aplicativo Excel visível
xlApp.Application.Visible = True
'Cria a planilha
Set wkb = xlApp.workbooks.Add
'seleciona a primeira planilha
Set objSheet = xlApp.Activeworkbook.sheets(1)
objSheet.Activate
'Insere os dados nas células desejadas
objSheet.cells(1, 3).Value = "Nome do Cliente"
objSheet.cells(2, 3).Value = "Avelino Sampaio"
'Ajusta o tamanho das colunas
objSheet.columns.autofit
'Salva a planilha no formato 97-2003
wkb.saveas FileName:=CurrentProject.Path & "\ListaClientes.xls", FileFormat:=56
'Fecha tudo
wkb.Close
Set objSheet = Nothing
Set wkb = Nothing
xlApp.Quit
Set xlApp = Nothing
MsgBox "A planilha foi criada...", vbInformation, "Aviso"
End Sub

Vamos supor agora, que você queira inserir dados neste arquivo já criado (ListaClientes.xls), mas na segunda planilha (Planilha2).  Acompanhe os comentários do código:

Public Sub fncAlterarPlanilha()
Dim xlApp As Object
Dim wkb As Object
Dim objSheet As Object
'Abre o Excel
Set xlApp = CreateObject("excel.application")
'Torna o aplicativo Excel visível
xlApp.Application.Visible = True
'Abre o arquivo ListaClientes.xls
Set wkb = xlApp.workbooks.Open(CurrentProject.Path & "\ListaClientes.xls")
'Adiciona uma segunda planilha ao arquivo
wkb.sheets.Add
'Variável objSheet assume a segunda planilha. 
'Insira o nome padrão fornecido pelo Excel (plan2 ou Planilha2)
Set objSheet = xlApp.Activeworkbook.sheets("planilha2")
'Altera o nome da planilha
objSheet.Name = "ClientesDesativados"
'Seleciona a segunda planilha
objSheet.Activate
'Insere os dados nas células desejadas
objSheet.cells(1, 1).Value = "Nome do Cliente"
objSheet.cells(2, 1).Value = "Luiz Henrique"
'Ajusta o tamanho das colunas
objSheet.columns.autofit
'Salva a planilha
wkb.Save
'Fecha tudo
wkb.Close
Set objSheet = Nothing
Set wkb = Nothing
xlApp.Quit
Set xlApp = Nothing
MsgBox "A planilha foi atualizada...", vbInformation, "Aviso"
End Sub

Bom estudo!


 

 


Não há comentário

Envie seu comentário: